How to refer to an instance variable with the same name as a property in a nested object

[kennydo]

I'm trying to create a class that represents a basic CronJob, with some properties that will be defined in instances of the class. For these examples, I've boiled it down to just the name property for simplicity.

In a Kubernetes CronJob resource, there is a metadata object which has a name property as well.

My naive first attempt to do this failed:

import "@k8s/api/batch/v1/CronJob.pkl"

class Job {
    name: String

    function createResource(): CronJob = new {
        metadata {
            name = name
        }
    }
}

myJob : Job = new {
    name = "myJob"
}

fails = myJob.createResource()

with

$ pkl eval weird.pkl
–– Pkl Error ––
A stack overflow occurred.

┌─ 9625 repetitions of:
│ 32 | name = name
│             ^^^^
│ at weird#Job.createResource.metadata.name

Which makes sense due to lazy evaluation and name resolution. But how do I set metadata.name to the name value of the instance?

I see on https://pkl-lang.org/main/current/language-reference/index.html#name-resolution that there is an outer scope that exists. But when I try to use that, it still fails:

import "@k8s/api/batch/v1/CronJob.pkl"

class Job {
    name: String

    function createResource(): CronJob = new {
        metadata {
            name = outer.name
        }
    }
}

myJob : Job = new {
    name = "myJob"
}
fails = myJob.createResource()

returns:

$ pkl eval weird.pkl
–– Pkl Error ––
Cannot find property `name` in object of type `k8s.api.batch.v1.CronJob`.

32 | name = outer.name
            ^^^^^^^^^^
at weird#Job.createResource.metadata.name

this.name also fails with a stack overflow.

Extending the CronJob class seems to work with outer.name:

import "@k8s/api/batch/v1/CronJob.pkl"

class Job extends CronJob {
    hidden name: String

    metadata {
        name = outer.name
    }
}

myJob : Job = new {
    name = "myJob"
}

But this still fails when it comes the more deeply nested metadata object.

import "@k8s/api/batch/v1/CronJob.pkl"

class Job extends CronJob {
    hidden name: String

    metadata {
        name = outer.name
    }

    spec {
        schedule = "* * * * * *"
        jobTemplate {
            metadata {
                name = outer.name
            }
        }
    }
}

myJob : Job = new {
    name = "myJob"
}

fails with:

$ pkl eval weird.pkl
–– Pkl Error ––
Cannot find property `name` in object of type `k8s.api.batch.v1.CronJob#JobTemplateSpec`.

38 | name = outer.name
            ^^^^^^^^^^
at weird#Job.spec.jobTemplate.metadata.name

[translatenix]

Perhaps I'm missing an easier solution, but "renaming" the outer property with local jobName = name should work.

[kennydo]

I think this would work, but it is not ideal to duplicate the class name in the property name just to work around this unexpected behavior.

[bioball]

Typically what I do here is to add a local self = this.

import "@k8s/api/batch/v1/CronJob.pkl"

class Job {
    local self = this

    name: String

    function createResource(): CronJob = new {
        metadata {
            name = self.name
        }
    }
}

By the way, the function here isn't providing any value. You can just make that a fixed property. This is a little nicer because the value gets cached. Methods currently get re-computed every time they are called; Pkl does not memoize methods.

class Job {
    local self = this

    name: String

    fixed resource: CronJob = new {
        metadata {
            name = self.name
        }
    }
}

[kennydo]

Thanks! This works great. It's unfortunate that we would need to have this line in almost all of our classes though, since we'd be setting the metadata.name property in most (if not all) of our resources. Are there any plans to define self by default?

[translatenix]

I think what should be done is to improve either the scoping rules or the semantics of outer..