-
-
Notifications
You must be signed in to change notification settings - Fork 71
/
build.gradle.kts
122 lines (104 loc) · 3.27 KB
/
build.gradle.kts
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
import org.jetbrains.changelog.Changelog
// fun properties(key: String) = project.findProperty(key).toString()
fun properties(key: String) = providers.gradleProperty(key)
fun environment(key: String) = providers.environmentVariable(key)
plugins {
id("java") // Java support
alias(libs.plugins.gradleIntelliJPlugin) // Gradle IntelliJ Plugin
alias(libs.plugins.changelog) // Gradle Changelog Plugin
}
group = properties("pluginGroup").get()
version = properties("pluginVersion").get()
repositories {
mavenCentral()
}
dependencies {
implementation(libs.annotations)
}
java {
toolchain {
languageVersion.set(JavaLanguageVersion.of(17))
}
}
sourceSets {
main {
java.srcDir("src")
resources.srcDir("resources")
}
}
intellij {
pluginName.set(properties("pluginName"))
version.set(properties("platformVersion"))
type.set(properties("platformType"))
updateSinceUntilBuild.set(true)
downloadSources = true
}
changelog {
groups.empty()
repositoryUrl.set(properties("pluginRepositoryUrl"))
}
/**
* Simple function to load HTML files and remove the surrounding `<html>` tags. This is useful for maintaining changes-notes
* and the description of plugins in separate HTML files which makes them much more readable.
*/
fun htmlFixer(filename: String): String {
if (!File(filename).exists()) {
logger.error("File $filename not found.")
} else {
return File(filename).readText().replace("<html>", "").replace("</html>", "")
}
return ""
}
tasks {
wrapper {
gradleVersion = properties("gradleVersion").get()
}
buildSearchableOptions {
enabled = false
}
withType<JavaCompile> {
options.encoding = "UTF-8"
options.compilerArgs.add("-Xlint:all")
}
patchPluginXml {
pluginDescription.set(htmlFixer("resources/META-INF/description.html"))
sinceBuild.set(properties("pluginSinceBuild"))
untilBuild.set(properties("pluginUntilBuild"))
val changelog = project.changelog
changeNotes.set(properties("pluginVersion").map { pluginVersion ->
with(changelog) {
renderItem(
(getOrNull(pluginVersion) ?: getUnreleased())
.withHeader(false)
.withEmptySections(false),
Changelog.OutputType.HTML,
)
}
})
}
runPluginVerifier {
val versions = properties("pluginVerifierIdeVersions")
.get()
.split(",")
.map(String::trim)
.filter(String::isNotEmpty)
// Kinda useless since the pluginVerifier will cry out
// anyway, but may not setting a version will be implemented at some point.
if (versions.isNotEmpty()) {
ideVersions.set(versions)
}
}
publishPlugin {
dependsOn("patchChangelog")
token.set(System.getenv("PUBLISH_TOKEN"))
// Use beta versions like 2020.3-beta-1
channels.set(properties("pluginVersion").map {
listOf(it
.split('-')
.getOrElse(1) { "default" }
.split('.')
.first()
)
})
}
}